dodawanie artykulacji w perkusji do określonych dźwięków

Piotrek24

Witam,
ten skrypt służy do oznaczania wszystkich dźwięków perkusyjnych na jednym systemie pięciolinijnym o określonej wysokości.
Można w ten sposób zaoszczędzić mnóstwo czasu, szczególnie przy importowaniu perkusji midi z innego programu.
Niestety nie ma odpowiedniego narzędzia w finale do globalnego dodawania artykulacji w perkusji.
Mamy na przykład zapisany rytm na całym zestawie perkusyjnym, a chcemy dodać oznaczenie tylko do jednego instrumentu.
Ponieważ notacja perkusyjna nie jest ustandaryzowana, może być to szczególnie przydatne przy używaniu instrumentów, których zapis wymaga opisu słownego, lub piktogramu, np. szczotki, pałki, filce.
Takie piktogramy można zrobić przy użyciu czcionki finale percussion font w narzędziu artykulacja.
Skrypt wymaga, żeby utworzyć dodatkowy plik finale z trzema systemami perkusji o nazwie Drum Set 1, Drum Set 2 i Drum Set 3.
Oczywiście wszystkie z nich mają taką samą mapę perkusyjną.
C:\Users\Audio\AppData\Roaming\MakeMusic\Finale 2014.5\FinaleScript\Moje skrypty\artykulacja_perkusji.musx
Skrypt kopiuje system perkusji do nowego pliku, gdzie zostaje wyizolowana wysokość dźwięku, którą należy podać tam, gdzie jest komentarz w skrypcie na ten temat (przed uruchomieniem).
Wyizolowana wysokośc jest umieszczona w środkowym systemie, dźwięki o wysokości wyższej są w systemie górnym, a niższe poniżej. Następnie uruchamiane jest polecenie apply articulation do wyizolowanego (środkowego systemu).
Przed uruchomieniem trzeba wpisać numer artykulacji z mapy artykulacji tam gdzie jest komentarz na ten temat.
Na koniec wszystkie 3 systemy są łączone do górnego systemu. System jest kopiowany z powrotem do pliku pierwotnego, a plik szablon zostaje zamknięty bez zapisania.
Na deser: skrypt informuje o zakończeniu działania.

//sytem perkusji musi się nazywać Drum Set!!!!
selection tool
menu item "edit/edit filter"
button "None"
button "All"
button OK

layer 1
active layer only
select all
//copy
copy

menu item "edit/select region"
dropdown "Drum Set" near "From"
dropdown "Drum Set" near "Through"
RETURN
//otwiera plik szablon
open dialog
press alt "n"
type "C:\Users\Audio\AppData\Roaming\MakeMusic\Finale 2014.5\FinaleScript\Moje skrypty\artykulacja_perkusji.musx"
button "Select"
select all
menu item "edit/select region"
dropdown "Drum Set 1" near "From"
dropdown "Drum Set 1" near "Through"
RETURN
paste
//wkleja zawartość
select all
//zaznacza dwa górne systemy
menu item "edit/select region"
dropdown "Drum Set 1" near "From"
dropdown "Drum Set 2" near "Through"
RETURN
press alt "q"
//split point tu trzeba wpisać wartość, czyli midi note number
type "46"
button ok

select all
menu item "edit/select region"
dropdown "Drum Set 2" near "From"
dropdown "Drum Set 2" near "Through"
RETURN
press ctrl "x"
//wycina środkową perkusję
select all
menu item "edit/select region"
dropdown "Drum Set 3" near "From"
dropdown "Drum Set 3" near "Through"
RETURN
paste
//wkleja na dół
select all
menu item "edit/select region"
dropdown "Drum Set 1" near "From"
dropdown "Drum Set 2" near "Through"
RETURN
//drugi split point trzeba wpisać midi note number +1
press alt "q"
type "47"
button ok
select all
menu item "edit/select region"
dropdown "Drum Set 2" near "From"
dropdown "Drum Set 2" near "Through"
RETURN
//dodaje artykulację
menu item "Utilities/Apply Articulation"
//tu trzeba wpisać wartość
type "91"
button ok
select all
//zaznacza wszysrko
menu item "edit/select region"
dropdown "Drum Set 1" near "From"
dropdown "Drum Set 3" near "Through"
RETURN
selection tool
//implode music
press "1"
//select radio button "Top staff of selection"
press alt "t"
button ok
select all
//zaznacza górny system
menu item "edit/select region"
dropdown "Drum Set 1" near "From"
dropdown "Drum Set 1" near "Through"
RETURN
//kopiuje
copy
press ctrl "w"
button "nie"
//zamyka bez zapisania

//otwiera poprzedni dokument
select all
menu item "edit/select region"
dropdown "Drum Set" near "From"
dropdown "Drum Set" near "Through"
RETURN
//wkleja
active layer only
paste
don't hide other layers
message "Skrypt zakończył działanie"

DanielFirlej

Bardzo interesujący skrypt - z niecierpliwością czekam na kolejne